【Access VBA】テーブルのデータを思い通りに加工する方法（後編）

Private Sub バッチ集計2_Click()
    
    Dim SQL_DAO_KS As String
    Dim DB_KS As DAO.Database
    Dim RS_KS As DAO.Recordset
    Dim Qdf As QueryDef
    
    'コードマスタを実行順に並べ替え
    SQL_DAO_KS = "SELECT * FROM T09更新用SQLマスタ WHERE 起動時 = Yes ORDER BY 起動時順番;"
    Set DB_KS = CurrentDb()
    Set RS_KS = DB_KS.OpenRecordset(SQL_DAO_KS)
    
    RS_KS.MoveFirst
    
    '順番に処理
    Do Until RS_KS.EOF
        If RS_KS.Fields(6).Value = "クエリ" Then  '中間クエリの作成
            If ExtQry(RS_KS.Fields(3).Value) = False Then
                Set Qdf = CurrentDb.CreateQueryDef(RS_KS.Fields(3).Value, RS_KS.Fields(2).Value)
                Set Qdf = Nothing
            End If
        ElseIf RS_KS.Fields(6).Value = "テーブル" Then  '中間テーブルの作成
            If ExtTbl(RS_KS.Fields(3).Value) = False Then
                DB_KS.Execute RS_KS.Fields(2).Value
            End If
        ElseIf RS_KS.Fields(7).Value = True Then  'プロシージャの実行
            Run RS_KS.Fields(2).Value
        Else
            DB_KS.Execute RS_KS.Fields(2).Value  'SQLを実行
        End If
        RS_KS.MoveNext
    Loop
    
    RS_KS.Close: Set RS_KS = Nothing
    DB_KS.Close: Set DB_KS = Nothing
    
    '中間クエリとテーブルの削除
    SQL_DAO_KS = "SELECT * FROM T09更新用SQLマスタ WHERE 起動時 = Yes AND 中間物名称 Is Not Null ORDER BY 起動時順番;"
    Set DB_KS = CurrentDb()
    Set RS_KS = DB_KS.OpenRecordset(SQL_DAO_KS)

    RS_KS.MoveFirst
    Do Until RS_KS.EOF
        If RS_KS.Fields(6).Value = "クエリ" Then
            CurrentDb.QueryDefs.Delete RS_KS.Fields(3).Value
        Else
            CurrentDb.TableDefs.Delete RS_KS.Fields(3).Value
        End If
        RS_KS.MoveNext
    Loop
    RS_KS.Close: Set RS_KS = Nothing
    DB_KS.Close: Set DB_KS = Nothing

    Me.F04月別カテゴリ集計DS.SourceObject = "F04月別カテゴリ集計DS"

End Sub